Auto Rescue Triggers Version.. umm.. I lost count.

[Nekler BlazingWolf]

#CLASS 0
#ALIAS ron {#T+ autorescue;#VAR ARescue ON}
#ALIAS roff {#T- autorescue;#VAR ARescue OFF}
#ALIAS addgroup {tog paging;#T+ Add_Group;who ingroup;#wa 2000;#T- Add_Group;#sa Group Add Off;tog paging}
#ALIAS addtank {#VAR tanklist %additem( %proper( %1), @tanklist);#SA %1 ADDED TO TANK LIST}
#ALIAS addres {#VAR rescuelist %additem( %proper( %1), @rescuelist);#SA %1 ADDED TO RESCUE LIST}
#ALIAS clearres {rescuelist = "";#echo Rescue list - Cleared.}
#ALIAS cleartanks {tanklist = "";#echo Tank list - Cleared.}
#ALIAS delres {#var rescuelist %delitem( %proper( %1), @rescuelist);#SA %1 REMOVED FROM RESCUE LIST}
#ALIAS deltank {#var tanklist %delitem( %proper( %1), @tanklist);#SA %1 REMOVED FROM TANK LIST}
#ALIAS dispres {#SA CURRENT RESCUE LIST:;#forall {@rescuelist} {#sa %{i}}}
#ALIAS disptanks {#SA CURRENT TANK LIST:;#forall {@tanklist} {#sa %{i}}}
#VAR tanklist {}
#VAR rescuelist {}
#VAR ARescue {}
#TRIGGER {^You flee} {#T- autorescue;#VAR ARescue OFF}
#TRIGGER {^You rejoin the land of the living...} {#T- autorescue;#VAR ARescue OFF}
#KEY F12 {#forall {@rescuelist} {rescue %i}
#STAT {AutoRescue is @ARescue}

#CLASS {autorescue} {disable}
#TRIGGER {* switches targets..} {#if (%ismember( %1, @tanklist|@rescuelist)) {} {look}}
#TRIGGER {* fighting *({@rescuelist})*} {#if (%1 != "") {} {rescue %1}}
#TRIGGER {* {hits|slashes|crushes|misses|whips|pierces|smashes|sting|stings|drains|strikes|pummels|pummel|strike|slash|pierce|whip|drain|smash|crush|pound|pounds|hit|claw|claws|touch|touches} *({@rescuelist})*} {#if (%1 != "") {rescue %1}}
#TRIGGER {* attacks ({@rescuelist}), landing *} {rescue %1}
#TRIGGER {({@rescuelist}) dodges (*) attack.} {#if (%2 = your) {} {rescue %1}}
#TRIGGER {({@rescuelist}) blocks (*) attack with {his|her|its} shield!} {#if (%2 = your) {} {rescue %1}}
#TRIGGER {({@rescuelist}) parries (*) futile lunge at {him|her|it}.} {#if (%2 = your) {} {rescue %1}}
#TRIGGER {({@rescuelist}) deflects (*) blow, and strikes back at *!} {#if (%2 = your) {} {rescue %1}}
#TRIGGER {You fail the rescue.} {#cw high,red}
#CLASS 0

#CLASS {Add_Group} {disable}
#TRIGGER {~[(*)~] (%w)} {#IF (%ismember( %2, @tanklist)) {} {addres %2}}
#CLASS 0


Ok, this is a set I picked up off this board and made some changes to.
Copy everything fromt he first #class 0 to the last #class 0 and stick it in a txt file. In zmud, go to Settings/Import/Script to import them
It works in condensed mode or normal mode.
It puts a status indicator in your status bar, so if you already have something there, remove the #stat line from the above script and add it manually, or just leave it out.
If you flee or die, it will turn off the rescue triggers. Reason I added that was because if you flee, and go back into the room to assist without getting a heal, you tend to start rescueing again and die anyway.
The F12 key spam rescues everyone on your rescue list.

Alias Explenation:
ron : Turns autorescue on
roff : Turns autorescue off
addgroup : does a who ingroup and adds everyone to your rescue list that isn't in your tank list (make tank list first)
addtank : Adds a tank to the tanks list
addres : Adds a name to the rescue list
clearres : Clears the rescue list
cleartanks : Clears the tank list
delres : Deletes a name from the rescue list
deltank : Deletes a name from the tanks list
dispres : Shows all the names in the rescue list
disptanks : Shows all the names in the tanks list

Known problems:
Once in awhile, it will fire off a rescue command to rescue the mob. Still looking into that. Doesn't effect anything though.
I haven't added anything yet for the new combat messages in normal mode. Should be doing that soonish.
Found out the non-condensed trigger needs a lil work. It fires on too many things, heh.

[Vigis]

Tried out yer trigger Nek, has 1 annoying glitch though.
If there a pile of stuff on the ground, it adds whatever it is to the rescue list.
Example: [2] a iron ration. It adds a to the list.
[3] corpse lies here. It adds corpse.

Anyway to fix this? And while we at it get rid of the "I'm Being attacked echo?


Thanks :)

Vigis

[Nekler BlazingWolf]

Yeah, make sure the "Add_Group" trigger class is disabled. It should only be enabled when you type "addgroup" and should shut itself back off after five seconds.
Might be a problem with zmud ignoring the {disable} part of the class when you import them. *shrug*

[Nassis]

You, just like everyone else, dont trigger rescue off mirror images getting smashed.

Poor illuses. As long as displace and images are left, nothing seems to happen. Then displace drops, which leads to all images vanishing - and poor illus has no protection left. It's a hard life...

[Nekler BlazingWolf]

Sorry, my test subject is only a lvl 35 warrior, so I haven't had the chance to group with many illusionists. ;)
Thanks for bringing it up though. Will try to remember to add it now. :)