Low-spam Anti-Zap triggers

Scripts and support for your favorite MUD client.
Jhorr
Sojourner
Posts: 515
Joined: Sun Feb 25, 2001 6:01 am

Low-spam Anti-Zap triggers

Postby Jhorr » Mon Nov 01, 2004 5:28 am

Here's a rough trigger set I wrote for Toraza. When you type 'addvokers' the triggers generate a list of just the invokers in the group. When you try to cast a spell and are out, the triggers go through the list and send the vokers a tell indicating you are done with that spell.

For the set to work, you have to adjust your aliases that you use to cast the spells. Just insert #var currentspell <spellname>. For example:

#alias {cloud} {gsay casting - Incendiary Cloud - ....;#var currentspell Cloud;c 'incend'}

Without further adieu, here is the trigger set:

#CLASS AntiZap {enable}
#alias {addvokers} {#t+ AddgroupTemp; #t+ Addvoker; cleargrouplist; clearvokers; tog paging; group}
#alias {addtogroup} {#additem grouplist %1}
#alias {addvoker} {#additem vokerlist %1; #SA %1 ADDED TO INVOKER LIST}
#alias {clearvokers} {vokerlist = ""; #echo INVOKER list - Cleared.}
#alias {cleargrouplist} {grouplist = ""; #echo GROUP list - Cleared.}
#alias {delvoker} {#var vokerlist %delitem( %1, @vokerlist); #SA %1 REMOVED FROM INVOKER LIST}
#alias {dispvokerlist} {#SA CURRENT INVOKER LIST:; #forall {@vokerlist} {#SA %{i}}}
#alias {dispgrouplist} {#SA CURRENT GROUP LIST:; #forall {@grouplist} {#SA %{i}}}
#alias {buildvokerlist} {#forall {@grouplist} {who %{i}};#t- AddgroupTemp;#wait 5000;#t- Addvoker;tog paging;#delitem vokerlist <your invoker's name here>;#echo Done}
#CLASS 0

#CLASS Addvoker {disable}
#action {Invoker ] (%w)} {addvoker %1}
#CLASS 0

#CLASS AddgroupTemp {disable}
#action {Unsplit coins} {#T+ Add_Group}
#CLASS 0

#CLASS Add_Group {disable}
#action {$} {#T- Add_Group; #delitem grouplist copper;buildvokerlist}
#action {* (%w)} {addtogroup %1}
#CLASS 0

#action {You don't have that spell memorized} {#if (@currentspell=Inferno or @currentspell=Meteorswarm or @currentspell=BallLightning or @currentspell=Cloud or @currentspell=Thunderblast) {#forall {@vokerlist} {tell %{i} Done @currentspell!}} {#noop}}
Jhorr
Sojourner
Posts: 515
Joined: Sun Feb 25, 2001 6:01 am

Postby Jhorr » Mon Nov 15, 2004 8:07 am

When you cut and paste this, check the following line after you've entered it:

#action {Invoker ] (%w)} {addvoker %1}

Check the spaces between 'Invoker' and the ']', make sure it's identical to the MUD output when you 'who' an invoker... it gets screwed up due to the different fonts or something between the BBS and the Zmud program

Return to “MUD Client Help”

Who is online

Users browsing this forum: No registered users and 16 guests