tintin++ targeting / spellup system

Scripts and support for your favorite MUD client.
Kindi
Sojourner
Posts: 405
Joined: Mon Nov 09, 2009 12:42 am

tintin++ targeting / spellup system

Postby Kindi » Fri Jun 11, 2010 12:43 am

compatible with tintin++ 2.00.1

Code: Select all

/*
   Using t1 <name> to assign targets that will show up with (t1) after their name
   and can be used as variables $targets[1] in any other alias, like vits or scales.
   Case sensitive. Example usage:
   
   t1 Lilithelle: assigns Lilithelle to $targets[1]
   look: Lilithelle (t1) stands here.

   #alias ft {c 'full heal' $targets[1]}
   Lilithelle (t1) staggers from a fearsome blow!
   ft: casts full heal at Lilithelle

   #alias v {c 'vit' %1}
   #alias {v{[1-9]}} {v $targets[%1];}
   Lilithelle (t1) group-says 'vit out'
   v1: casts vit at Lilithelle
   
   Combine this with capture windows to show group-says or 'group' command results
   easily, and you can cast spells at appropriate targets with three button presses.
   'ts' lists current targets, and 't1 none' resets to blank (nonresponsive with other
   aliases and triggers)

*/
#loop {1} {9} {temp} {#list targets add none}
#alias {t{[1-9]} %*}
{
   #if {"$targets[%1]" != "none"}
   {
      #unsub {~%%1$targets[%1]%%2}
   };
   #if {"%2" != "none"}
   {
      #sub {~%%1%2%%2} {%%1%2 (t%1)%%2}
   };
   #show <168>Target %1 ($targets[%1]) is now: %2;
   #var targets[%1] %2;
}
#alias {ts} {#loop {1} {9} {temp} {#if {"$targets[$temp]" != "none"} {#show <168>Target $temp is: $targets[$temp]<088>}}}
#alias {tclear} {#loop {1} {9} {temp} {#if {"$targets[$temp]" != "none"} {t$temp none}}}


#nop Glancing, assisting, and bandaging targets assigned with aliases
#alias {gh} {#loop {1} {9} {temp} {#if {"$targets[$temp]" != "none"} {gl $targets[$temp]}}}
#alias {bandall} {#loop {1} {9} {temp} {#if {"$targets[$temp]" != "none"} {bandage $targets[$temp]}}}
#alias {ast} {assist $targets[1]}


#nop Assigning $enemy variable for use in any other alias, like damage spells or blinds
#nop Example: #alias {da} {c 'magic missile %1}; #alias {dae} {da $enemy};
#alias {x} {#var enemy %1;#show <168>Enemy is now: %1<088>}
#alias {ge} {gl $enemy}
#alias {gm} {gl me}
#var enemy none

Return to “MUD Client Help”

Who is online

Users browsing this forum: No registered users and 1 guest